Hallo,

Ik heb het topic van de stinger_drop_mod gelezen, sa mission builder gedownload, en precies gedaan wat daar staat. Nu krijg ik bij het compileren de error die op het plaatje (bijgevoegd) staat. De "totally stripped" crasht bij het laden. Ik heb alles al geprobeerd en ben ten einde raad. Kan iemand helpen?

Groeten, Sef

Hallo,

In het ugeloade zip bestandje staat de gedecompileerde versie (txt bestand). Het "create_objects_in_object_group "CRACK"" heb ik wel kunnen vinden, de "name_thread 'INT'" niet. Ik heb acter ":MAIN_5808'" de stinger threads staan. Als je graag wil dat ik de gedecompileerde van de "schone" scm file online zet, of de schone scm-file als bestand, met je dat maar even schrijven.

Is het overigens mogelijk om de nauwkeurig heid te verhogen? De banden knappen alleen als de auto er vol overheen rijdt, en niet als ie maar met twee banden er overheen rijdt. Dan zouden er toch twee banden moeten knappen...

Sef

Dat was inderdaad de juiste plek om de code toe te voegen. Je kon "name_thread" niet vinden omdat je een andere ini file gebruikt waar de namen van de commando's instaan. Bij jou heet die alleen "thread".

Op zich ziet het zo goed uit, je hebt in je bericht niet gemeld of het zo wel of niet werkt.

Wat betreft de onnauwkeurigheid, dat zou wel kunnen, maar dat is niet heel erg eenvoudig. Want daarvoor moet je de afstand van elk wiel tot het midden van de auto kennen, en dat is bij elk model natuurlijk weer anders. Daarom heb ik voor deze oplossing gekozen.

Waarom krijg ik dan de error "Label "0" niet gevonden"?

Waarom krijg ik dan de error "Label "0" niet gevonden"?

Zo te zien heb je de code die je hebt ingevoegd niet eerst met behulp van de code converter omgezet naar sanny-builder formaat, zoals ik had gezegd.

De code die je invoegt, moet er zo uitzien:

:Stinger_thread
03A4: name thread "STING"
0247: request_model #TEMP_STINGER2
038B: load_requested_models
0004: 32@ = 0
029B: 7@ = init_object #TEMP_STINGER2 at 0@ 1@ 2@
0177: set object 7@ z angle to 3@
01C7: remove_object_from_mission_cleanup_list 7@
0007: 4@ = 0@
000F: 4@ -= 2.0
000B: 0@ += 2.0
0007: 5@ = 1@
000F: 5@ -= 2.0
000B: 1@ += 2.0

:Stinger_loop
0001: wait 250 ms
0007: 6@ = -1
053E: 6@ = get_random_car_with_actors -1 in_area 4@ 5@ 0@ 1@
00D6: if 0
8039: NOT 6@ == -1// integer values
004D: jump_if_false @Stinger_timer
04FE: deflate_tire 1 on_car 6@
04FE: deflate_tire 2 on_car 6@
04FE: deflate_tire 3 on_car 6@
04FE: deflate_tire 4 on_car 6@

:Stinger_timer
00D6: if 0
0019: 32@ > 10000
004D: jump_if_false @Stinger_loop
0249: release_model #TEMP_STINGER2
0108: destroy object 7@
004E: end_thread

:stinger_sniff_thread
03A4: name thread "ST_SNIF"

:stinger_sniff_loop
0001: wait 100 ms
00D6: if 0
0256: player $PLAYER_CHAR defined
004D: jump_if_false @stinger_sniff_loop
00D6: if 1
00E1: key pressed 0 17
00DF: actor $PLAYER_ACTOR driving
004D: jump_if_false @stinger_sniff_loop
03C0: 10@ = actor $PLAYER_ACTOR car
0407: create coordinate 0@ 1@ 2@ from car 10@ offset 0.0 -2.5 1.0
0174: 3@ = car 10@ z_angle
0009: 3@ += 90.0// floating-point values
02CE: 2@ = ground z 0@ 1@ 2@
000B: 2@ += 0.1
004F: create thread @Stinger_thread 0@ 1@ 2@ 3@
0001: wait 500 ms
0002: jump @stinger_sniff_loop

Een van de verschillen, en degene die jou foutmelding veroorzaakte, was dat lokale variabelen in sannybuilder niet de '@' voor het nummertje van de variabele hebben staan, maar erachter.(dus 0@ in plaats van @0)

Als je bovenstaande code gebruikt in plaats van de code die jij hebt ingevoegd, zou het moeten werken.

Bedankt, hij werkt nu met de volledige main file. Maar ik heb nog een vraag: Hoe kun je het stinger-drop geluidje (ding, klak-klak) erin zetten?

Sef

Bedankt, hij werkt nu met de volledige main file. Maar ik heb nog een vraag: Hoe kun je het stinger-drop geluidje (ding, klak-klak) erin zetten?

Sef

Da's niet helemaal simpel..

maar deze code zou het moeten doen..

:Stinger_thread
03A4: name thread "STING"
0004: 32@ = 0
029B: 7@ = init_object #TEMP_STINGER2 at 0@ 1@ 2@
0177: set object 7@ z angle to 3@
01C7: remove_object_from_mission_cleanup_list 7@
097A: play_audio_at 0@ 1@ 2@ event 1125 

0007: 4@ = 0@
000F: 4@ -= 2.0
000B: 0@ += 2.0
0007: 5@ = 1@
000F: 5@ -= 2.0
000B: 1@ += 2.0

:stinger_unfold
0001: wait 10 ms
00D6: if 
03D2:   wav 3 ended 
004D: jump_if_false @Stinger_unfold 
097A: play_audio_at 0@ 1@ 2@ event 1104 

:Stinger_loop
0001: wait 250 ms
0007: 6@ = -1
053E: 6@ = get_random_car_with_actors -1 in_area 4@ 5@ 0@ 1@
00D6: if 0
8039: NOT 6@ == -1// integer values
004D: jump_if_false @Stinger_timer
04FE: deflate_tire 0 on_car 6@
04FE: deflate_tire 1 on_car 6@
04FE: deflate_tire 2 on_car 6@
04FE: deflate_tire 3 on_car 6@

:Stinger_timer
00D6: if 0
0019: 32@ > 10000
004D: jump_if_false @Stinger_loop
0108: destroy object 7@
004E: end_thread

:stinger_sniff_thread
03A4: name thread "ST_SNIF"
0247: request_model #TEMP_STINGER2
03CF: load_wav 1822 as 3 
:Stinger_wavload
0001: wait 0 ms 
00D6: if 
03D0:   wav 3 loaded 
004D: jump_if_false @Stinger_wavload 
038B: load_requested_models

:stinger_sniff_loop
0001: wait 100 ms
00D6: if 0
0256: player $PLAYER_CHAR defined
004D: jump_if_false @stinger_sniff_loop
00D6: if 1
00E1: key pressed 0 17
00DF: actor $PLAYER_ACTOR driving
004D: jump_if_false @stinger_sniff_loop
03C0: 10@ = actor $PLAYER_ACTOR car
0407: create coordinate 0@ 1@ 2@ from car 10@ offset 0.0 -2.5 1.0
0174: 3@ = car 10@ z_angle
0009: 3@ += 90.0// floating-point values
02CE: 2@ = ground z 0@ 1@ 2@
000B: 2@ += 0.1
004F: create thread @Stinger_thread 0@ 1@ 2@ 3@
0001: wait 500 ms
0002: jump @stinger_sniff_loop

Heel erg bedankt voor die code, maar ik speelde laast de begin missie dat je moet fietsen, liet een stinger vallen, maar de banden van de ballas auto knapte niet. Waarschijnlijk worden missieauto's niet als "gewone auto's" beschouwd... Is hier iets aan te doen?

Sef

Heel erg bedankt voor die code, maar ik speelde laast de begin missie dat je moet fietsen, liet een stinger vallen, maar de banden van de ballas auto knapte niet. Waarschijnlijk worden missieauto's niet als "gewone auto's" beschouwd... Is hier iets aan te doen?

Sef

Inderdaad, missie-auto's worden apart behandeld, net als je eigen auto.

Met de huidige opzet van deze code is daar helaas niets aan te doen ...

OK. Bedankt voor alles.

Sef