Tutorial Account-systeem

Gemaakt door Sandra18[NL]

Andere Tutorials van mij:

>>Objecten<<

>>Menu's<<

>>CheckPoints+AdminArea<<

** In deze tutorial ga ik uitleggen hoe je een account-systeem kan maken inclusief het opslaan van gegevens.

In veel servers kan je een eigen account aanmaken met een eigen wachtwoord.

Als je zo'n account hebt, kunnen er persoonlijke gegevens worden opgeslagen zoals, geld, aantal kills enzovoort.

(Welke info er word opgeslagen is natuurlijk afhankelijk van de server).

Als er een account word aangemaakt word er in de map 'scriptfiles' een nieuw bestand aangemaakt.

Deze heeft geen extentie (zoals .txt of .inc) maar je kan de bestanden gewoon met 'kladblok' openen en bewerken.

Voor een account systeem heb je de volgende include bestanden nodig:

- a_samp.inc

- dudb.inc

- dutils.inc

- dini.inc

De laatste 3 bestanden kan je >>hier<< downloaden (Puma, thnx voor de link )

met 'dini' kan je comunniseren met bestanden.

We gaan de volgende functies gebruiken:

- dini_Exists(udb_encode(naam)) ---> Dit kijkt of het bestand 'naam' wel of niet bestaat

- dini_Create(udb_encode(naam)) ---> Deze functie maakt een bestand aan met de naam 'naam'

- dini_IntSet(udb_encode(naam), "variabele", waarde); ---> Deze functie maakt in het bestand 'naam' een nieuwe variabele "variabele" en zet daar de waarde 'waarde' achter.

- dini_Get(udb_encode(naam), "variabele"); ---> Haalt de waarde die achter de variabele staat in het bestand 'naam' op

Voor de 'naam' gebruiken we de naam van de speler dus we noemen het 'playername'

Om die te achterhalen zullen we de volgende functie gaan gebruiken:

new playername[MAX_PLAYERNAME];
GetPlayerName(playerid, playername, sizeof(playername));

OKe, nu gaan we stap voor stap het script in elkaar zetten:

We beginnen bovenaan het script met de includes en de defines:

Je hoeft dutils en dini niet te 'includen' omdat die automatisch door dudb worden included.

We gebruiken 3 kleuren (rood, geel en groen)

#include <a_samp>
#include <dudb>

#define COLOR_RED 0xFF0000AA
#define COLOR_YELLOW 0xFFFF00AA
#define COLOR_GREEN 0x00FF00AA

Vervolgens moeten we een paar variabelen aanmaken.

We gebruiken:

- logged[MAX_PLAYERS] --> Hiermee slaan we voor elke speler zijn login-waarde op (0 = niet, 1=wel ingelogd)

- adminlevel[MAX_PLAYERS] --> Hiermee slaan we voor elke speler de adminlevel op

- money[MAX_PLAYERS] --> Hiermee slaan we voor elke speler het geld op

- playername[MAX_PLAYER_NAME] --> Definitie van playername

new logged[MAX_PLAYERS];
new adminlevel[MAX_PLAYERS];
new money[MAX_PLAYERS];
new playername[MAX_PLAYER_NAME];

Dan volgen nog 3 standaard callbacks:

main()
{
print("===============================");
print("AccountTutorial by Sandra18[NL]");
print("===============================");
}

public OnGameModeInit()
{
SetGameModeText("Tutorial Accounts by Sandra18[NL]");
AddPlayerClass(93, 1958.3783, 1343.1572, 15.3746, 269.1425, 0, 0, 0, 0, 0, 0);
return 1;
}


public OnPlayerRequestClass(playerid, classid)
{
SetPlayerPos(playerid, 1958.3783, 1343.1572, 15.3746);
SetPlayerCameraPos(playerid, 1968.3783, 1345.1572, 17.3746);
SetPlayerCameraLookAt(playerid, 1958.3783, 1343.1572, 15.3746);
return 1;
}

Dan volgt de OnPlayerConnect-callback:

Hier hoeven we alleen de login-waarde van de nieuwe speler op '0' te zetten, aangezien hij/zij nog niet ingelogd is als hij contact maakt met de server.

public OnPlayerConnect(playerid)
{
logged[playerid] = 0;
return 1;
}

Bij de OnPlayerSpawn-callback gaan we kijken of de speler wel of niet ingelogd is, is dat niet het geval, dan krijgt hij/zij een melding dat hij/zij zich nog moet inloggen:

public OnPlayerSpawn(playerid)
{
if(logged[playerid] == 0) {
SendClientMessage(playerid, COLOR_RED, "Je bent nog niet ingelogd! Gebruik /login [wachtwoord]!");
}
return 1;
}

Dan nu de OnPlayerCommandText-callback

Dit is het lastigste gedeelte dus lees het heel goed door en probeer te begrijpen wat er per regel gebeurt.

We beginnen met wat standaard 'defines':

public OnPlayerCommandText(playerid, cmdtext[])
{
new cmd[256],tmp[256], tmp2[256];
new idx;
new string[256];
cmd = strtok(cmdtext, idx);
GetPlayerName(playerid, playername, sizeof(playername));

Eerst maken we het /register [wachtwoord] commando:

(De teksten in het rood zijn aantekeningen)

(De rode aantekeningen gaan over de regel onder de aantekening zelf

//De speler typt /register in...

if(strcmp(cmd, "/register", true) == 0) {

//de tekst die achter '/register' wordt getypt, wordt opgeslagen in 'tmp'

tmp = strtok(cmdtext, idx);

//check of er überhaupt wat ingevuld word achter /register

if(!strlen(tmp)) {

//Als dat niet zo is, (!), dan moet er een berichtje worden verzonden:

SendClientMessage(playerid, COLOR_YELLOW, "USAGE: /register (password)");

}

//Als er wel wat ingevuld wordt....

else {

//....dan moet er worden gekeken of het bestand met de naam van de speler nog niet bestaat:

if (!dini_Exists(udb_encode(playername))) {

//Bestaat die nog niet, dan moet die worden aangemaakt:

dini_Create(udb_encode(playername));

//Vervolgens moet het wachtwoord worden opgeslagen:

dini_IntSet(udb_encode(playername), "password", udb_hash(tmp));

//Dan de variabelen 'adminlevel' en 'money', beiden met de waarde '0':

dini_IntSet(udb_encode(playername), "adminlevel", 0);

dini_IntSet(udb_encode(playername), "money", 0);

//Er moet een bericht gemaakt worden die wat info naar de speler gaat sturen:

format(string, sizeof(string), "Account %s aangemaakt! Je kunt nu inloggen met het wachtwoord: %s.", playername, tmp);

//Zend dat bericht naar de speler:

SendClientMessage(playerid, COLOR_YELLOW, string);

} //Dit was alles wat er moet gebeuren als er idd geregisteerd moet worden.

//Als blijkt dat de naam als geregisteerd is, dan moet er een bericht naar de speler verzonden worden:

else {

format(string, sizeof(string), "%s already registered.", playername,tmp);

SendClientMessage(playerid, COLOR_RED, string);

}}

return 1;

}

Nu doen we het /login [wachtwoord] commando op dezelfde manier:

// Als de speler het commando /login typt:

if(strcmp(cmd, "/login", true) == 0)

{

// Verkrijg de naam van de speler:

GetPlayerName(playerid, playername, sizeof(playername));

// Kijk of de speler al ingelogd is:

if(logged[playerid] == 1)

//Zo ja, dan moet er een bericht worden verzonden met de melding dat hij al ingelogd is.

{

SendClientMessage(playerid, COLOR_RED, "Je bent al ingelogd");

return 1;

}

// Sla de tekst (wachtwoord in dit geval) op in de variabele 'tmp' die achter /login getypt wordt:

tmp = strtok(cmdtext, idx);

// Als er niks word ingetypt achter /login, dan moet er een bericht verzonden worden:

if(!strlen(tmp)){

SendClientMessage(playerid, COLOR_YELLOW, "Gebruik: /login (wachtwoord)");

}

// Als er wel wat in wordt getypt....

else {

//...dan word er gekeken of het bestand met de spelersnaam wel bestaat (Met andere woorden: heeft diegene zich wel geregistreerd?

if (dini_Exists(udb_encode(playername))) {

// Zo ja, dan word uit zijn bestand de waarde achter "password" gehaald (zijn wachtwoord waarmee hij/zij zich geregisteerd heeft dus):

tmp2 = dini_Get(udb_encode(playername), "password");

// Als het wachtwoord dat de speler ingevoerd heeft niet overeenkomt met het wachtwoord in zijn bestand. (Let op het !=-teken), dan moet er een bericht worden verzonden met de melding dat hij/zij het verkeerde wachtwoord heeft getypt:

if (udb_hash(tmp) != strval(tmp2)) {

SendClientMessage(playerid, COLOR_RED, "Verkeerd wachtwoord!.");

}

// Komt het wachtwoord wel overeen....

else {

// Zet de loginwaarde van de speler op '1'

logged[playerid] = 1;

// Haal uit het bestand de waarde die achter "money" staat en sla die op in de variabele 'money[playerid]'

money[playerid] = dini_Int(udb_encode(playername), "money");

// Haal uit het bestand de waarde die achter "adminlevel" staat en sla die op in de variabele adminlevel[playerid]

adminlevel[playerid] = dini_Int(udb_encode(playername), "adminlevel");

// Stel een zin samen die aangeeft hoeveel geld en welke adminlevel de speler heeft:

format(string, sizeof(string), "%s, je bent nu ingelogd. Je hebt adminlevel %d en je hebt %d dollar", playername, adminlevel[playerid], money[playerid]);

// Stuur het bericht:

SendClientMessage(playerid, COLOR_GREEN, string);

// Geef de speler het bedrag dat zojuist in de money[playerid]-variabele is gezet:

GivePlayerMoney(playerid, money[playerid]);

}

// Dit was alles dat er moest gebeuren als de speler zich inlogt.

}

// Als het account met de spelersnaam nog niet bestaat (dus de speler heeft zich nog niet geregistreerd....:

else {

// ...Dan moet er een zin samengesteld worden die zegt dat het account met die spelers naam nog niet bestaat en dus nog geregistreerd moet worden

format(string, sizeof(string), "Het account %s, bestaat nog niet. Typ /register [wachtwoord] om een account te maken.", playername);

// Het bericht verzenden:

SendClientMessage(playerid, COLOR_RED, string);

}}

return 1;

}

Nou, dit waren de /register en /login commando's het is een beetje chaotisch, maarja, tis niet 1 van de makkelijkste dingen om uit te leggen...

Dan moeten we nu nog een commando maken waarmee je je admin kan maken:

Mijn idee was om in dit script 4 adminlevels te hebben:

level 0 = geen admin

level 1 = beginner-admin

level 2 = gevorderde-admin

level 3 = hoofd-admin.

Om je met dit commando hoofdadmin te maken moet je jezelf eerst met rcon inloggen: /rcon login [rcon-pass]

if(strcmp(cmd, "/maakmijadmin", true) == 0)

{

// Heeft de speler zich met rcon ingelogd? (met /rcon login [rcon-pass]:

if(IsPlayerAdmin(playerid)) {

// Heeft de speler zich wel eerst ingelogd? (met /login [wachtwoord]:

if(logged[playerid] == 1) {

// Heeft de speler nog niet level 3? (let op het != teken)

if(adminlevel[playerid] != 3) {

// Voldoet de speler aan de voorwaarden, dan word de adminlevel[playerid] op '3' gezet:

adminlevel[playerid] = 3;

// Stuur nu een berichtje:

SendClientMessage(playerid, COLOR_GREEN, "Je bent nu hoofdadmin! Gefeliciteerd!");

}

// Als de speler al level 3 is, dan moet er een berichtje worden verzonden:

else {

SendClientMessage(playerid, COLOR_RED, "Je bent al hoofdadmin!");

}}

// Als de speler zich nog niet heeft ingelogd met /login [wachtwoord]:

else {

SendClientMessage(playerid, COLOR_RED, "Je moet je eerst inloggen /login [wachtwoord]");

}}

// Als de speler zich nog niet heeft ingelogd met /rcon login [rcon-pass]:

else {

SendClientMessage(playerid, COLOR_RED, "Je moet je eerst met rcon inloggen! (/rcon login [rcon-pass])");

}

return 1;

}

Je kan uiteraard ook de level (en het geld) van een speler aanpassen door het getal achter de desbetreffende variabele te veranderen.

Als je nu commando's wilt maken die alleen door level 1 adminsgebruikt mogen worden.

Dan voeg je in die functie de volgende regel toe:

if(adminlevel[playerid] == 1

De volgende tekens kan je gebruiken.

== gelijk aan ...

< kleiner dan ...

> groter dan ...

<= kleiner of gelijk aan ...

>= groter of gelijk aan ...

!= niet gelijk aan ...

Nog een voorbeeldje:

Als een commando alleen door admins die level 2 of hoger hebben, dan voeg je deze regel toe:

if(adminlevel[playerid] >= 2

Om de OnPlayerCommandText-callback af te sluiten:

return 0;
}

Tot slot moeten we ervoor zorgen dat de gegevens van de speler worden opgeslagen zodra hij/zij de server verlaat.

Dit doen we in de callback 'OnPlayerDisconnect':

public OnPlayerDisconnect(playerid, reason)

{

// Verkrijg de naam van de speler:

GetPlayerName(playerid, playername, sizeof(playername));

// Haal het geld van de speler op en sla die op in de variabele 'money[playerid]'

money[playerid] = GetPlayerMoney(playerid);

// Zet in het spelerbestand achter de variabele 'money' het bedrag dat de speler heeft

dini_IntSet(udb_encode(playername), "money", money[playerid]);

// Zet in het spelerbestand achter de variabele 'adminlevel' de level van de speler:

dini_IntSet(udb_encode(playername), "adminlevel", adminlevel[playerid]);

// Zet de loginwaarde van die playerid weer op '0'

logged[playerid] = 0;

return 1;

}

Oke, dat was het, dat was de hele code...

Omdat kwaliteit van filmpjes zo slecht zijn, kan je niet lezen welke berichten er in de chat verscheinen, daarom doe ik het nu in plaats van een filmpje nu maar met woorden en een plaatje:

- Ik join de server met de naam 'GtaForum'

- Ik kies een karakter uit (maar 1 keus in dit geval)

- Ik spawn en er komt een melding: "Je bent nog niet ingelogd! Gebruik /login [wachtwoord]!"

- Ik verzin het wachtwoord 'abcdefg' (hoe origineel )

- Ik typ in "/login abcdefg", nu krijg ik een melding:

"Het account GtaForum, bestaat nog niet. Typ /register [wachtwoord] om een account te maken."

- Ik typ "/register abcdefg", nu komt er de melding:

"Account GtaForum aangemaakt! Je kunt nu inloggen met het wachtwoord: abcdefg."

- Nu typ ik "/login" (dus zonder wachtwoord. Nu staat er "Gebruik: /login [wachtwoord]"

- Nu een verkeerd wachtwoord: "/login 1234567". Nu staat er "Verkeerd wachtwoord!."

- Nu het goede wachtwoord: "/login abcdefg" en nu staat er

""GtaForum, je bent nu ingelogd. Je hebt adminlevel 0 en je hebt 0 dollar"

- Nu typ ik /rcon login [mijn rcon pass] en nu staat er "You are now logged in as an admin"

- Nu kan ik /maakmijadmin typen en er komt de melding: ""Je bent nu hoofdadmin! Gefeliciteerd!"

- Ik geef mezelf even (met een extra commando (niet bij dit script inbegrepen)) 9751 dollar.

- Nu verlaat ik de server.

- Als ik nu naar de map 'scriptfiles' ga en daar het bestand 'GtaForum' open, dan staan daar mijn gegevens.

(zie afbeelding onderaan).

- Als ik nu weer de server in ga, dan typ ik "/login abcdefg" dan staat er:

""GtaForum, je bent nu ingelogd. Je hebt adminlevel 3 en je hebt 9751 dollar"

Zo, nu doen mijn vingers zeer van het typen

Omdat het hier nogal chaotisch is, heb ik het script op internet gezet zodat het er wat duidelijker uitziet

Download >>hier<< het hele script met de commentaren:

Download >>hier<< het hele script zonder de commentaren.

Als je nog vragen hebt, of foutjes ziet, of andere opmerkingen hebt, kan je ze in dit topic stellen.

P.s. Als je tekens zoals [ ] ( ) _ in je spelersnaam hebt staan, dan veranderd sa:mp dat in de namen van de user-files zoals je kunt zien aan mijn user-file "Sandra18[NL]" is veranderd naar "Sandra18_05NL_06"

Dit heeft geen concequenties op het inloggen enzo.

Veel succes en plezier ermee

Groetjes Sandra

Bewerkt: 19 maart 200817 jaren door =>Sandra<=

ja heb ik allebij maar alleen ik kan er in niemand anders

en sorry dat ik het weer hier neer zet

ik heb het account systeem geïnstalleerd het werkt top

maar als er mensen in mijn server komen krijgen ze geen geld in het begin

heeft iemand daar mischien een oplossing op???

ik heb het account systeem geïnstalleerd het werkt top

maar als er mensen in mijn server komen krijgen ze geen geld in het begin

heeft iemand daar mischien een oplossing op???

bij OnPlayerConnect zet je

GivePlayerMoney(playerid, hierhetbedrag);

Pad als ze zich inloggen, krijgen ze het geld terug wat bij hun vorige bezoek aan je server is opgeslagen, terug.

okej bedankt

ik heb een error in mijn server dat gaat alsvolgt :

C:\bureaublad\samp\gamemodes\stuntmod.pwn(550) : error 017: undefined symbol "PlayerMoney"

wat kan ik hier tegen doen???

ik heb een error in mijn server dat gaat alsvolgt :

C:\bureaublad\samp\gamemodes\stuntmod.pwn(550) : error 017: undefined symbol "PlayerMoney"

wat kan ik hier tegen doen???

new PlayerMoney;

Dat bestand dudb moet ik dat in de map zetten van alle includes? Wat ik kan het bestand niet vinden. Kun je ook maken dat als je de server in komt dat ja automatisch wordt ingelogt?

EDIT@HIERONDER:

Ik heb hem gedownload maar nu kan ik het bestand dudb niet vinden in al die mapjes. Dus kan ik hem niet in het mapje includes zetten. En nu kan ik niks testen

Bewerkt: 1 januari 200817 jaren door Remcconen

Het bestandje moet je downloaden op de site die in het begin is gegeven en vervolgens in de volgende map zetten (wel in je SA-MP map, natuurlijk ): Pawn map --> Includes. Daarna zal Pawno hem herkennen en kun je hem gebruiken.

Dat weet ik maar ik kan dat bestand niet vinden. En hoe kun je zo instellen dat iedereen automatisch wordt ingelogt?

Ik krijg 11 fouten die ik nu èèn voor èèn probeer te fixen (ik begon met 36 fouten)

Over dit stuk:

	  if(logged[playerid] == 0)
{
SendClientMessage(playerid, COLOR_RED, "You ar not logged in! Pleas use /login");
}
return 1;
}

Hier na komt nog meer van die shit zoals:

	if(gTeam[playerid] == TEAM_SF) {
SetPlayerColor(playerid,COLOR_BLUE); // Green
}

Maar ik krijg ''invalid function or declaration'' en op die regel staat dus dit

	if(gTeam[playerid] == TEAM_SF) {

Als ik dan kijk naar mijn script zie ik dus dat ik 2x een ''if'' heb staan onder ''public OnPlayerSpawn(playerid)''

Hoe moet ik een 2e ''if'' maken onder ''public OnPlayerSpawn(playerid)''?

Bewerkt: 4 januari 200817 jaren door Danny_k

	 
public OnPlayerSpawn(playerid)
{
if(logged[playerid] == 0)
{
	SendClientMessage(playerid, COLOR_RED, "You ar not logged in! Pleas use /login");
}

if(gTeam[playerid] == TEAM_SF) 
{
	SetPlayerColor(playerid,COLOR_BLUE); // Green
}

if(gTeam[playerid] == TEAM_WATDANOOK) 
{
	SetPlayerColor(playerid,COLOR_RozeMetPaarsRandje); 
}
return 1;
}

Yes, bedankt!

hoe kan je instellen dat als je dood gaat en weer levend wordt dat je geld krijgt???

hoe kan je instellen dat als je dood gaat en weer levend wordt dat je geld krijgt???

OnPlayerSpawn....

Ik heb een probleem: Waar kan ik in dat zip bestand dudb.inc vinden? Ik heb die andere 2 wel gevonden, en ik heb ook een bestand dat db.inc heet gevonden, is dat hem?